mirror of
https://github.com/priyanshujain/sanderling.git
synced 2026-10-02 11:07:10 +00:00
114 lines
3.6 KiB
Kotlin
114 lines
3.6 KiB
Kotlin
import com.google.protobuf.gradle.id
|
|
|
|
plugins {
|
|
kotlin("jvm") version "2.1.21"
|
|
application
|
|
id("com.gradleup.shadow") version "9.0.0-rc2"
|
|
id("com.google.protobuf") version "0.10.0"
|
|
}
|
|
|
|
version = findProperty("sanderling.version") as String? ?: "0.0.0-dev"
|
|
|
|
java {
|
|
toolchain {
|
|
languageVersion.set(JavaLanguageVersion.of(17))
|
|
}
|
|
}
|
|
|
|
kotlin {
|
|
jvmToolchain(17)
|
|
}
|
|
|
|
val grpcVersion = "1.68.0"
|
|
val protobufVersion = "3.25.5"
|
|
val maestroVersion = "2.4.0"
|
|
|
|
// Maestro 2.4.0 still declares grpc-netty:1.50.2 and grpc-okhttp:1.50.2 which
|
|
// were compiled against AbstractManagedChannelImplBuilder removed in grpc-core 1.64+.
|
|
// Force them to the version we pin so they stay binary-compatible.
|
|
// Also exclude GraalVM JS — not used by our sidecar and causes shadow JAR expansion errors.
|
|
configurations.all {
|
|
resolutionStrategy.eachDependency {
|
|
if (requested.group == "io.grpc" &&
|
|
(requested.name == "grpc-netty" || requested.name == "grpc-okhttp")) {
|
|
useVersion(grpcVersion)
|
|
because("align grpc transport with grpc-core version")
|
|
}
|
|
}
|
|
exclude(group = "org.graalvm.js")
|
|
exclude(group = "org.graalvm.sdk")
|
|
exclude(group = "org.graalvm.regex")
|
|
exclude(group = "org.graalvm.truffle")
|
|
}
|
|
|
|
dependencies {
|
|
implementation("dev.mobile:maestro-client:$maestroVersion")
|
|
implementation("dev.mobile:maestro-utils:$maestroVersion")
|
|
|
|
implementation("io.grpc:grpc-netty-shaded:$grpcVersion")
|
|
implementation("io.grpc:grpc-protobuf:$grpcVersion")
|
|
implementation("io.grpc:grpc-stub:$grpcVersion")
|
|
implementation("com.google.protobuf:protobuf-java:$protobufVersion")
|
|
implementation("javax.annotation:javax.annotation-api:1.3.2")
|
|
|
|
implementation("org.slf4j:slf4j-simple:2.0.16")
|
|
|
|
testImplementation(kotlin("test"))
|
|
testImplementation("io.grpc:grpc-testing:$grpcVersion")
|
|
testImplementation("io.grpc:grpc-inprocess:$grpcVersion")
|
|
testImplementation("junit:junit:4.13.2")
|
|
testImplementation("org.junit.jupiter:junit-jupiter:5.11.3")
|
|
testRuntimeOnly("org.junit.vintage:junit-vintage-engine:5.11.3")
|
|
testRuntimeOnly("org.junit.platform:junit-platform-launcher:1.11.3")
|
|
}
|
|
|
|
protobuf {
|
|
protoc {
|
|
artifact = "com.google.protobuf:protoc:$protobufVersion"
|
|
}
|
|
plugins {
|
|
id("grpc") {
|
|
artifact = "io.grpc:protoc-gen-grpc-java:$grpcVersion"
|
|
}
|
|
}
|
|
generateProtoTasks {
|
|
all().forEach { task ->
|
|
task.plugins {
|
|
id("grpc")
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
sourceSets {
|
|
main {
|
|
proto {
|
|
srcDir(rootProject.file("proto"))
|
|
}
|
|
}
|
|
}
|
|
|
|
application {
|
|
mainClass.set("dev.sanderling.sidecar.MainKt")
|
|
}
|
|
|
|
// The Go binary embeds this fat JAR by fixed path (internal/sidecar/assets/
|
|
// sidecar-all.jar). Pin the shadow output name so the embed step doesn't
|
|
// depend on `version`.
|
|
tasks.named<com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar>("shadowJar") {
|
|
archiveFileName.set("sidecar-all.jar")
|
|
exclude("META-INF/*.SF", "META-INF/*.DSA", "META-INF/*.RSA")
|
|
// The iOS driving modules arrive transitively through maestro-client but
|
|
// the sidecar only drives Android, so strip the iOS UITest runner bundles
|
|
// and iOS-only classes from the fat JAR. Compilation keeps the full
|
|
// classpath; only the packaged artifact drops these.
|
|
exclude("driver-iphoneos/**", "driver-iPhoneSimulator/**")
|
|
exclude("ios/**", "xcuitest/**", "hierarchy/**")
|
|
}
|
|
|
|
// JUnit 4 (vintage) for the gRPC GrpcCleanupRule + JUnit 5 (jupiter)
|
|
// for the rest. UseJUnitPlatform with the vintage engine handles both.
|
|
tasks.test {
|
|
useJUnitPlatform()
|
|
}
|